110 OPTION BASE 0
120 LET kei=0
130 LET nag=0
140 INPUT PROMPT "帯グラフ： 項目数は？（その他は含まない） ":n
150 DIM X$(n),Y(n),W(n),Z(n),COL$(10)
160 LET COL$(1)="青色"
170 LET COL$(2)="黄緑"
180 LET COL$(3)="赤色"
190 LET COL$(4)="水色"
200 LET COL$(5)="黄色"
210 LET COL$(6)="赤紫"
220 LET COL$(7)="灰色"
230 LET COL$(8)="紺色"
240 LET COL$(9)="深緑"
250 LET COL$(10)="青緑"
260 FOR I=1 TO n  
270    INPUT PROMPT "項目の 名称 を入力してください。 ":NAMAE$
280    INPUT PROMPT "その項目の 数値 を入力してください。 ":NUMBER
290    LET X$(I)=NAMAE$
300    LET Y(I)=NUMBER
310 NEXT I
320 INPUT PROMPT "その他 の項目の数値を入力してください。( なければ 0 ） ":NUM
330 INPUT PROMPT "数値の 単位 を入力してください。 ":UNIT$
340 FOR I=1 TO n
350    LET kei=kei+Y(I)
360 NEXT I
370 LET S=kei+NUM
380 FOR I=1 TO n
390    LET W(I)=INT(1000*(Y(I)/S)+0.5)/10
400 NEXT I
410 LET H=INT(1000*(NUM/S)+0.5)/10
420 FOR i=1 TO n
430    FOR j=i+1 TO n
440       IF Y(j)<Y(i) THEN
450          LET kari=Y(i)
460          LET ka$=X$(i)
470          LET ri=W(i)
480          LET Y(i)=Y(j)
490          LET X$(i)=X$(j)
500          LET W(i)=W(j)
510          LET Y(j)=kari
520          LET X$(j)=ka$
530          LET W(j)=ri
540       END IF
550    NEXT j
560 NEXT i
570 PRINT
580 FOR I=n TO 1 STEP -1
590    PRINT COL$(n-I+1);" :　";
600    PRINT X$(I);"  ";
610    PRINT Y(I);UNIT$;"   ";
620    PRINT USING "##.#":W(I);
630    PRINT " %"
640 NEXT I
650 IF NUM=0 THEN GOTO 690
660 PRINT  COL$(n+1);" :  その他　";NUM;UNIT$;"  ";
670 PRINT USING "##.#":H;
680 PRINT " %"
690 PRINT
700 FOR I=n TO 1 STEP -1
710    LET nag=nag+W(I)
720    LET Z(n-I+1)=nag
730 NEXT I
740 SET bitmap SIZE 640,400
750 SET WINDOW 0,639,399,0
760 LET Z(0)=0
770 FOR I=1 TO n
780    SET AREA COLOR I+1
790    PLOT AREA:100+5*Z(I-1),50;100+5*Z(I),50;100+5*Z(I),130;100+5*Z(I-1),130
800 NEXT I
810 SET AREA COLOR n+2
820 PLOT AREA:100+5*Z(n),50;600,50;600,130;100+5*Z(n),130
830 SET COLOR 1
840 PLOT LINES: 100,50;600,50;600,130;100,130;100,50
850 PLOT LINES: 100,40;600,40
860 FOR I=0 TO 10
870    PLOT LINES:100+50*I,40;100+50*I,45
880 NEXT I
890 END